Le code 128

Ce code complexe permet le codage des 128 caractères ASCII. Le résultat est très dense, notamment pour le codage des valeurs numériques. Il est utilisé entre autre sur certaine feuille de sécurité sociale et sur certaines étiquettes de transport pour inscrire le numéro SSCC. (Identifiant du colis)

Etudions le mode d'encodage.

• La largeur d'une barre fine est appelée le module.
• Il existe des barres de 1, 2, 3 ou 4modules; de même pour les espaces.
• Il existe 107 motifs, chacun codé sur 11 modules comprenant 3 barres et 3 espaces (Le motif de STOP possède une 4ème barre).
• Il existe 3 tables donnant le caractère ou la fonction affecté à chaque motif.
  * La table A contient les lettres majuscules, les chiffres, les ponctuations, des codes de contrôle et des codes spéciaux.
  * La table B contient les lettres majuscules et minuscules, les chiffres, les ponctuations et des codes spéciaux.
  * La table C contient des paires de chiffres (Permettant de doubler la densité) et des codes spéciaux.
• Il faut des marges blanches de 10 modules au moins à gauche et à droite.
Il y a un caractère de START au début du code. Il existe 3 caractères de START déterminant la table utilisée au départ.
Le code se termine par un caractère de STOP.
Des caractères spéciaux (99, 100 & 101) permettent de passer d'une table à l'autre; le caractère SHIFT (98) permute le caractère suivant entre les tables A & B.
Les codes de fonction (FNC1 à FNC4) ne sont pas tous définis.
Une clé de contrôle doit être ajoutée; sa valeur est calculée en totalisant la valeur du START puis la valeur de chaque motif multipliée par son rang; puis en prenant le reste de la division de cette somme par 103.
Dans le tableau suivant le module de barre est symbolisé par "1" et le module d'espace par "0".
Les colonnes "Code ASCII" et "Caractère" indiquent l'emplacement des motifs dans la police "code128.ttf" (Voir plus loin)
Le caractère n° 0 (Espace) est obtenue avec le code32 ou avec le code 212 car certains outils de programmation ne peuvent pas utiliser le code 32.

Exemple de clé de contrôle en utilisant la table B pour : ZB65
104 + (1 x 58) + (2 x 34) + (3 x 22) + (4 x 21) = 380
380 / 103 = 3, reste 71 qui est la valeur de la clé.

Version 2.00 de la police : Le code des caractères 95 et suivant a été modifié par rapport à la version 1.00. La fonction d'encodage (voir plus bas) a été modifiée en conséquence.

La création des codes barres.

• La méthode graphique où chaque barre est "dessinée" comme un rectangle plein. Cette méthode permet de calculer la largeur de chaque barre au pixel près et de travailler sur des multiples de la largeur d'un pixel du périphérique utilisé. Cela donne une bonne précision surtout si le périphérique a une faible densité comme c'est le cas des écrans et des imprimantes à jet d'encre. Cette méthode demandes des routines de programmations spécifiques et ne permet pas de réaliser des codes barres avec un logiciel courant.
• La police spécifique dans laquelle chaque caractère est remplacé par le code barre d'un caractère. Cette méthode permet d'utiliser n'importe quel programme comme un traitement de texte ou un tableur (Par exemple OpenOffice, le clone gratuit de MSoffice !) Les mises à l'échelles en fonction du corps (La taille quoi) choisi peuvent entrainer de petites distorsions du dessin des barres. Avec une imprimante laser il n'y a aucun problème.

La police " code128.ttf "

Copiez ce fichier dans le répertoire des polices, le plus souvent : C:\WINDOWS\FONTS

Structure d'un code 128

• L'un des trois code de START, le plus souvent START B.
• Autant de caractères que nécessaires, des codes spéciaux permettent de passer d'une table à l'autre. Un algorithme intelligent permettra d'utiliser la ou les tables donnant le code barre le plus court possible.
• Une clé de contrôle.
• Un code STOP.

Un petit programme pour tester tout ça

Ce programme de test ne gère pas les codes de contrôle ASCII, il utilise les tables B & C avec optimisation de la longueur du code obtenu.

Public Function Code128$(chaine$)
  'V 2.0.0
  'Paramètres : une chaine
  'Parameters : a string
  'Retour : * une chaine qui, affichée avec la police CODE128.TTF, donne le code barre
  '         * une chaine vide si paramètre fourni incorrect
  'Return : * a string which give the bar code when it is dispayed with CODE128.TTF font
  '         * an empty string if the supplied parameter is no good
  Dim i%, checksum&, mini%, dummy%, tableB As Boolean
  Code128$ = ""
  If Len(chaine$) > 0 Then
  'Vérifier si caractères valides
  'Check for valid characters
    For i% = 1 To Len(chaine$)
      Select Case Asc(Mid$(chaine$, i%, 1))
      Case 32 To 126, 203
      Case Else
        i% = 0
        Exit For
      End Select
    Next
    'Calculer la chaine de code en optimisant l'usage des tables B et C
    'Calculation of the code string with optimized use of tables B and C
    Code128$ = ""
    tableB = True
    If i% > 0 Then
      i% = 1 'i% devient l'index sur la chaine / i% become the string index
      Do While i% <= Len(chaine$)
        If tableB Then
          'Voir si intéressant de passer en table C / See if interesting to switch to table C
          'Oui pour 4 chiffres au début ou à la fin, sinon pour 6 chiffres / yes for 4 digits at start or end, else if 6 digits
          mini% = IIf(i% = 1 Or i% + 3 = Len(chaine$), 4, 6)
          GoSub testnum
          If mini% < 0 Then 'Choix table C / Choice of table C
            If i% = 1 Then 'Débuter sur table C / Starting with table C
              Code128$ = Chr$(210)
            Else 'Commuter sur table C / Switch to table C
              Code128$ = Code128$ & Chr$(204)
            End If
            tableB = False
          Else
            If i% = 1 Then Code128$ = Chr$(209) 'Débuter sur table B / Starting with table B
          End If
        End If
        If Not tableB Then
          'On est sur la table C, essayer de traiter 2 chiffres / We are on table C, try to process 2 digits
          mini% = 2
          GoSub testnum
          If mini% < 0 Then 'OK pour 2 chiffres, les traiter / OK for 2 digits, process it
            dummy% = Val(Mid$(chaine$, i%, 2))
            dummy% = IIf(dummy% < 95, dummy% + 32, dummy% + 105)
            Code128$ = Code128$ & Chr$(dummy%)
            i% = i% + 2
          Else 'On n'a pas 2 chiffres, repasser en table B / We haven't 2 digits, switch to table B
            Code128$ = Code128$ & Chr$(205)
            tableB = True
          End If
        End If
        If tableB Then
          'Traiter 1 caractère en table B / Process 1 digit with table B
          Code128$ = Code128$ & Mid$(chaine$, i%, 1)
          i% = i% + 1
        End If
      Loop
      'Calcul de la clé de contrôle / Calculation of the checksum
      For i% = 1 To Len(Code128$)
        dummy% = Asc(Mid$(Code128$, i%, 1))
        dummy% = IIf(dummy% < 127, dummy% - 32, dummy% - 105)
        If i% = 1 Then checksum& = dummy%
        checksum& = (checksum& + (i% - 1) * dummy%) Mod 103
      Next
      'Calcul du code ASCII de la clé / Calculation of the checksum ASCII code
      checksum& = IIf(checksum& < 95, checksum& + 32, checksum& + 105)
      'Ajout de la clé et du STOP / Add the checksum and the STOP
      Code128$ = Code128$ & Chr$(checksum&) & Chr$(211)
    End If
  End If
  Exit Function
testnum:
  'si les mini% caractères à partir de i% sont numériques, alors mini%=0
  'if the mini% characters from i% are numeric, then mini%=0
  mini% = mini% - 1
  If i% + mini% <= Len(chaine$) Then
    Do While mini% >= 0
      If Asc(Mid$(chaine$, i% + mini%, 1)) < 48 Or Asc(Mid$(chaine$, i% + mini%, 1)) > 57 Then Exit Do
      mini% = mini% - 1
    Loop
  End If
Return
End Function 

Depuis la première parution de cette page, j'ai reçu de nombreuses versions dans différents langages, les voici :

 

Les codes EAN.UCC 128 Ce sont des codes 128 dont le contenu est normalisé et correspond à une utilisation dans le domaine de la logistique. Un code EAN128 commence par le caractère Fnc1 suivi d'un ou plusieurs champs de données. Chaque champ commence par un AI (Identificateur d'application) qui indique ce que contient le champ (Numéro de colis ou date de péremption par exemples) suivi par les données elles-même. Ces données sont de longueur fixe ou variable, numériques ou alphanumériques, avec ou sans somme de controle et tout ceci en fonction de chaque AI. Si un champ est à longueur variable,que la longueur maximale n'est pas utilisé et qu'il n'est pas le dernier champ, alors on le fait suivre par un caractère Fnc1. Certains AI nécessite que les données soient suivies par une somme de controle; celle-ci est calculée de la manière suivante : Les chiffres sont numérotés de droite à gauche, puis on calcule x la somme des chiffres pairs et y la somme des chiffres impairs Calculons z = x + 3 * y Soit m le nombre divisible par 10 immédiatement supérieur à z La somme de contrôle est : m - z J'ai réalisé un petit programme permettant de créer facilement des codes EAN128 et prenant en compte ces caractéristiques. Fichier d'auto-installation : Fichier ZIP sans installation :

Vous aimez cette page ? Elle vous est utile ? Cliquez ici !